«

»

এপ্রিল 22

স্যাস পরিচিতি – লেকচার ৪: পরিসংখ্যানের সারাংশ

 

[নিবন্ধনের লিংক] [কোর্সের মূল পাতা] [আগের পর্ব]

এই পর্বের ভূমিকা: 

আজকের পর্বে আমরা শিখবো কিভাবে উপাত্ত থেকে পরিসংখ্যানের বিভিন্ন সারাংশ বের করা যায়।

এই পর্বে ব্যবহৃত সমস্ত উপাত্ত এই লিংক থেকে ডাউন-লোড করা যাবে।

 

 শুরুর আগের কথা:

এই পর্বে আমরা অনেক পরিসংখ্যানের শব্দ ব্যবহার করব, যার ব্যাখ্যা বা সংজ্ঞা দেয়া হবে না। বর্তমান পরিসংখ্যান পরিচিতি কোর্স থেকে সেই শব্দগুলো সম্পর্কে ধারণা পেতে পারেন। এই লেকচারে আমরা কিভাবে বিভিন্ন পরিসংখ্যানের সারাংশ বের করতে পারব, তার উপর কেবল জোড় দেব।

 

পরিসংখ্যান বিষয়ক কৌতুক

পরিসংখ্যান বিষয়ক কৌতুক

 

নতুন লেকচারের ভিডিও – পর্ব ৪: পরিসংখ্যানের সারাংশ

আমার ইউটিউবের চ্যানেলের মাধ্যমে এইখানে ভিডিও অনুবিদ্ধ করলাম, আগ্রহীরা গ্রাহকশ্রেণিভুক্ত হতে পারেন।

আপনার অঞ্চলে ইউটিউব অবরুদ্ধ থাকলে সাথে দিলাম স্ক্রিনকাস্ট মিরর আর ভিডিও ডাউন-লোড (৩২.৬৬ মেগা) লিঙ্ক। সর্বশেষে আমার ওয়েবসাইটে মিরর

 

লেকচার সারসংক্ষেপ

সম্পূর্ণ ভিডিও দেখার পরে সারসংক্ষেপ দেখুন। নীচে বর্ণিত আলোচনাটি ভিডিওর অবিকল অনুলিখন নয়, সারসংক্ষেপ মাত্র। সম্পূর্ণ ভিডিও লেকচার না দেখলে সারসংক্ষেপ আলোচনা বুঝতে অসুবিধা হতে পারে।

 

 উপাত্তের অনুক্রম সম্পর্কে ধারণা পেতে চাই

* describing the data using contents;
proc contents data = MS;
run;

 উপাত্তের সারাংশ পেতে চাই

* describing the data using means;
Data MScond;
INPUT id trt gender $ age rel1 rel2 rel3;
Total = rel1 + rel2 + rel3;
IF Total GE 2 THEN Elig = ‘Yes’;
ELSE Elig = ‘No’;
DATALINES;
1 1 M 29 1 1 1
2 0 M 20 1 0 1
3 1 F 39 0 0 0
4 0 M 19 1 1 1
5 1 M 28 1 0 0
6 0 F 33 0 0 1
7 1 M 20 1 1 0
8 0 M 29 1 0 1
9 1 F 18 0 0 .
;
proc means DATA = MScond;
TITLE ‘Summary of MS variables’;
VAR age Total;
run;

 আরো বেশি সারাংশ পেতে চাই

* describing the data using means with specific options;
proc means DATA = MScond N NMISS
MIN Q1 MEDIAN Q3 MAX
RANGE STDDEV
SUM MEAN CLM
SKEWNESS KURTOSIS
MAXDEC = 2;
TITLE ‘Summary of MS variables’;
VAR age Total;
run;

  উপাত্তের অংশ বিশেষের সারাংশ আলাদা ভাবে পেতে চাই

* using BY option;
proc sort DATA = MScond;
TITLE ‘Sorting MS data by treatment group’;
BY trt;
run;
proc means DATA = MScond N NMISS MEAN STD MAXDEC = 2;
TITLE ‘Summary of MS variables by treatment group’;
VAR age Total;
BY trt;
run;

 উপাত্ত সাজিয়ে নেয়া ছাড়াই সরাসরি উপাত্তের অংশ বিশেষের সারাংশ আলাদা ভাবে পেতে চাই

* using CLASS option;
proc means DATA = MScond N NMISS MEAN STD MAXDEC = 2;
TITLE ‘Summary of MS variables by treatment group’;
VAR age Total;
CLASS gender;
run;

 সারাংশগুলি নিয়ে নতুন উপাত্ত বানাতে চাই

* describing the data using summary;
proc summary DATA = MScond;
TITLE ‘Summary of AGE’;
VAR age;
output out=sumdata mean=mean_age n=n var=var_age std=std_age
stderr=se_age min=min_age max=max_age
range=range_age cv=cv_age sum=sum_age
median=med_age;
run;
proc print DATA = sumdata;
run;

 এত কিছু পই পই করে বলে দিতে হলে তো সমস্যা। দুনিয়ার সর্ব প্রকার সারাংশ পেতে চাইলে সে ধরনের কোনো উপায় আছে কি?

* describing the data using univariate;
proc univariate DATA = MScond;
TITLE ‘Univariate summary of MS variables’;
VAR age Total;
run;

গাণিতিক সারাংশের সাথে তথ্যমূলক ছবি পাবার উপায় কি?

* describing the data using univariate and plots;
proc univariate DATA = MScond NORMAL PLOT;
TITLE ‘Summary of Age’;
VAR age;
QQPLOT age;
HISTOGRAM age;
INSET MEAN = ‘Mean of AGE’
STD = ‘SD of AGE’;
run;

 ঘটনসংখ্যা সারণী পাব কিভাবে?

* describing the data using freq;
proc freq DATA = MScond;
TITLE ‘Frequency table of MS variables’;
TABLES Total;
run;

 ঘটনসংখ্যা সারণী চেয়েছি, সাথে এত কিছু দিলে তো বিপদ। শুধু ঘটনসংখ্যা পাব কিভাবে?

* describing the data using freq with less columns;
proc freq DATA = MScond;
TITLE ‘Frequency table of MS variables’;
TABLES Total / NOCUM NOPERCENT;
run;

 ঘটনসংখ্যা সারণীর সাথে কাই-বর্গ  পরীক্ষণ পাওয়া সম্ভব?

* describing the data using freq with chi-sq;
proc freq DATA = MScond;
TITLE ‘Frequency table of MS variables’;
TABLES trt gender trt*gender / CHISQ;
run;

 স্টুডেন্ট টি প্রকল্পের পরীক্ষণ করে কিভাবে?

* t-test: comparing means;
proc ttest DATA=MScond;
TITLE ‘t-test Age of treated vs age of untreated’;
CLASS trt;
VAR age;
run;

 উইলকক্সন প্রকল্পের পরীক্ষণ করে কিভাবে?

* Wilcoxon-test: comparing means;
proc npar1way DATA=MScond WILCOXON;
TITLE ‘Wilcoxon-test Age of treated vs age of untreated’;
CLASS trt;
VAR age;
run;

 

আজ এ পর্যন্তই। প্রশ্ন থাকলে মন্তব্যের মাধ্যমে জানান; এইখানে অথবা পরবর্তী পর্বে জবাব দেয়ার চেষ্টা করব। আগে যেমন বলেছি, আপনার অন্য কোন কোর্সের বাড়ির কাজের সমাধান দেব না। আশা করি সাথে থাকবেন।

 

সূত্র:

www.ats.ucla.edu/stat/sas/

স্যাস সাপোর্ট

উইকি  পরিসংখ্যান ও সম্ভাবনা পরিভাষা

 

আগের লেকচারের লিঙ্ক:

ভূমিকা

স্যাস পরিচিতি – লেকচার ১ – বেইজ স্যাস খুঁটিনাটি

স্যাস পরিচিতি – লেকচার ২ – উপাত্ত আমদানি

স্যাস পরিচিতি – লেকচার ৩ – উপাত্ত পরিবর্ধন ও প্রদর্শন

 

Comments

comments

About the author

এহসান করিম

ঢাকা বিশ্ববিদ্যালয় থেকে ফলিত পরিসংখ্যানে পড়াশুনা করেছি এবং পরবর্তীতে পরিসংখ্যানে উচ্চশিক্ষার জন্য ব্রিটিশ কলাম্বিয়া বিশ্ববিদ্যালয়ে আসি। মূলত গবেষণার বিষয় কারণিক সিদ্ধান্ত।

Leave a Reply